import ru.landgrafhomyak.kotlin.kmp_gradle_build_helper.defineXomrkGiteaMavenRepo

buildscript {
	repositories {
		mavenCentral()
		maven("https://maven.landgrafhomyak.ru/")
	}

	dependencies {
		classpath("ru.landgrafhomyak.kotlin:kotlin-mpp-gradle-build-helper:v0.3k2.1.10")
	}
}

plugins {
	kotlin("multiplatform") version "2.2.10"
	`maven-publish`
}

group = "ru.landgrafhomyak.utility"
version = "0.1"

repositories {
	mavenCentral()
	maven("https://maven.landgrafhomyak.ru/")
}

kotlin {
	explicitApi()

	mingwX64()

	linuxX64()
	linuxArm64()

	macosX64()
	macosArm64()


	sourceSets {
		commonMain {
			dependencies {
				implementation("org.jetbrains.kotlin:kotlin-stdlib:${this@kotlin.coreLibrariesVersion}")
				implementation("ru.landgrafhomyak.utility:highlevel-try-finally:0.6")
				implementation("ru.landgrafhomyak.utility:closeable-state-1:1.2")
			}
		}

		// hierarchy
		val commonMain by getting
		val commonTest by getting

		val windowsMain by creating { dependsOn(commonMain) }
		val windowsTest by creating { dependsOn(commonTest) }
		mingwX64Main { dependsOn(windowsMain) }
		mingwX64Test { dependsOn(windowsTest) }

		val posixMain by creating { dependsOn(commonMain) }
		val posixTest by creating { dependsOn(commonTest) }

		val linuxMain by creating { dependsOn(posixMain) }
		val linuxTest by creating { dependsOn(posixTest) }
		linuxX64Main { dependsOn(linuxMain) }
		linuxX64Test { dependsOn(linuxTest) }
		linuxArm64Main { dependsOn(linuxMain) }
		linuxArm64Test { dependsOn(linuxTest) }

		val macosMain by creating { dependsOn(posixMain) }
		val macosTest by creating { dependsOn(posixTest) }
		macosX64Main { dependsOn(macosMain) }
		macosX64Test { dependsOn(macosTest) }
		macosArm64Main { dependsOn(macosMain) }
		macosArm64Test { dependsOn(macosTest) }
	}
}

publishing {
	repositories {
		defineXomrkGiteaMavenRepo("LanguageUtilities")
	}
}