import org.jetbrains.kotlin.gradle.dsl.JvmTarget
import org.jetbrains.kotlin.gradle.dsl.KotlinVersion
import ru.landgrafhomyak.kotlin.kmp_gradle_build_helper.*
import ru.landgrafhomyak.kotlin.kmp_gradle_build_helper.plugin.xomrk

buildscript {
	repositories {
		mavenCentral()
		maven("https://maven.landgrafhomyak.ru/")
	}

	dependencies {
		classpath("ru.landgrafhomyak.kotlin:kotlin-mpp-gradle-build:v0.3k2.1.10")
	}
}

group = "ru.landgrafhomyak.utility"
version = "0.4.4"

repositories {
	mavenCentral()
}

xomrk {
	kotlin {
		setCompatibilityWithKotlin(KotlinVersion.KOTLIN_2_0)
		optInContracts()

		defineAllMultiplatformTargets()

		jvmToolchain(8)
		jvm {
			withJava()

			compilations.configureEach {
				compileJavaTaskProvider?.configure {
					targetCompatibility = "1.8"
				}
				compileTaskProvider.configure {
					compilerOptions {
						jvmTarget = JvmTarget.JVM_1_8
						freeCompilerArgs.addAll("-Xallow-kotlin-package")
					}
				}
			}
		}

		sourceSets {
			commonMain {
				dependencies {
					compileOnly(kotlin("stdlib"))
				}
			}
			jvmMain {
				dependencies {
					compileOnly(kotlin("stdlib"))
				}
			}

			sourceSets.configureEach {
				if (name == "jvmMain") return@configureEach
				 if (name == "commonMain") return@configureEach
				dependencies {
					implementation(kotlin("stdlib"))
				}
			}
		}
	}

	publishing {
		repositories {
			defineXomrkGiteaMavenRepo()
		}
	}
}