import org.jetbrains.kotlin.gradle.dsl.JvmTarget
import org.jetbrains.kotlin.gradle.dsl.KotlinVersion
import ru.landgrafhomyak.kotlin.kmp_gradle_build_helper.*
import ru.landgrafhomyak.kotlin.kmp_gradle_build_helper.plugin.xomrk

buildscript {
	repositories {
		mavenCentral()
		maven("https://maven.landgrafhomyak.ru/")
	}

	dependencies {
		classpath("ru.landgrafhomyak.kotlin:kotlin-mpp-gradle-build:v0.3k2.1.10")
	}
}

group = "ru.landgrafhomyak.db"
version = "0.2"

repositories {
	mavenCentral()
	maven("https://maven.landgrafhomyak.ru/")
}

xomrk {
	kotlin {
		setCompatibilityWithKotlin(KotlinVersion.KOTLIN_2_0)
		optInContracts()
		explicitApi()

		jvmToolchain(8)
		jvm {
			compilations.configureEach {
				compileJavaTaskProvider?.configure {
					targetCompatibility = "1.8"
				}
				compileTaskProvider.configure {
					compilerOptions {
						jvmTarget = JvmTarget.JVM_1_8
					}
				}
			}
		}

		sourceSets {
			val kotlinStdlibDependency = "org.jetbrains.kotlin:kotlin-stdlib:${this@kotlin.coreLibrariesVersion}"
			jvmMain {
				dependencies {
					compileOnly(kotlinStdlibDependency)
					compileOnly("com.intellij:annotations:9.0.4")
					implementation("ru.landgrafhomyak.utility:highlevel-try-finally:0.5")
				}
			}
		}
	}

	publishing {
		repositories {
			defineXomrkGiteaMavenRepo()
		}

		forceSetAllMavenArtifactsId(project.name)
	}
}